PARAMI9I0515P
C     APPENDIX E   SAMPLE PROBLEM 1   PAGE 44 OF C24-1455-2
C     MATRIX ARITHMETIC
      DIMENSION A(7,8), B(7,7)
      SENSE LIGHT 1
      DO 1 I = 1, 7
      DO 1 J = 1, 7
      B(I,J) = 1./FLOATF(I+J-1)
1     A(I,J) = B(I,J)
      PRINT 13
13    FORMAT ( 15H1HILBERT MATRIX // )
      DO 71 J = 1, 7
71    PRINT 2, A(1,J), A(2,J), A(3,J),
     1 A(4,J), A(5,J), A(6,J), A(7,J)
2     FORMAT ( 1X, 7E14.7 )
      PRINT 15
15    FORMAT ( 8H0INVERSE // )
C
10    DO 6 K = 1, 7
      A(1,8) = 1.
      DO 3 I = 2, 7
3     A(I,8) = 0.
      DO 4 J = 2, 8
4     A(1,J) = A(1,J)/A(1,1)
      DO 5 J = 1, 7
      DO 75 I = 1, 6
C     SHIFT A ROW LEFT
75    A(I,J) = A(I + 1, J)
C     THEN RIGHT END OF THIS ROW GETS LEFT OF NEXT
      A(7,J) = A(1,J+1)
5     CONTINUE
C     FINALLY DO LEFT SHIFT OF WHAT WAS VECTOR
      DO 76 I = 1, 6
76    A(I,8) = A(I+1,8)
      DO 6 I = 1, 6
      A(7,8) = A(I,1)
      DO 6 J = 1, 7
      A(I,J) = A(I,J+1) - A(7,8) * A(7,J)
6     CONTINUE
      DO 79 J = 1, 7
79    PRINT 2, A(1,J), A(2,J), A(3,J),
     1 A(4,J), A(5,J), A(6,J), A(7,J)
C     TESTING SENSE LIGHT 1 TURNS IT OFF
      IF ( SENSE LIGHT 1 ) 11, 12
11    PRINT 16
16    FORMAT ( 15H0MATRIX PRODUCT // )
      DO 9 K = 1, 7
      DO 8 I = 1, 7
      A(I,8) = 0.0
      DO 8 J = 1, 7
8     A(I,8) = A(I,8) + A(I,J) * B(J,K)
9     PRINT 18, A(1,8), A(2,8), A(3,8),
     1 A(4,8), A(5,8), A(6,8), A(7,8)
18    FORMAT ( 1X, 7F14.8 )
      PRINT 17
17    FORMAT ( 15H0TWICE INVERTED // )
      GO TO 10
12    PRINT 7
7     FORMAT ( 1H1 )
      STOP 111
      END